/************************************************************************************
 * arch/arm/src/lm3s/lm3s_context.S
 * arch/arm/src/chip/lm3s_context.S
 *
 *   Copyright (C) 2009 Gregory Nutt. All rights reserved.
 *   Author: Gregory Nutt <spudmonkey@racsa.co.cr>
 *
 * Redistribution and use in source and binary forms, with or without
 * modification, are permitted provided that the following conditions
 * are met:
 *
 * 1. Redistributions of source code must retain the above copyright
 *    notice, this list of conditions and the following disclaimer.
 * 2. Redistributions in binary form must reproduce the above copyright
 *    notice, this list of conditions and the following disclaimer in
 *    the documentation and/or other materials provided with the
 *    distribution.
 * 3. Neither the name NuttX nor the names of its contributors may be
 *    used to endorse or promote products derived from this software
 *    without specific prior written permission.
 *
 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
 * "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
 * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
 * FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
 * COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
 * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
 * BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS
 * OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED
 * AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
 * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
 * ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
 * POSSIBILITY OF SUCH DAMAGE.
 *
 ************************************************************************************/

/************************************************************************************
 * Included Files
 ************************************************************************************/

#include <nuttx/config.h>
#include <arch/irq.h>
#include "cortexm3_nvic.h"

/************************************************************************************
 * Preprocessor Definitions
 ************************************************************************************/

/************************************************************************************
 * Global Symbols
 ************************************************************************************/

	.syntax		unified
	.thumb
	.file		"lm3s_context.S"

/************************************************************************************
 * Macros
 ************************************************************************************/

/************************************************************************************
 * Public Functions
 ************************************************************************************/

/**************************************************************************
 * Name: up_saveusercontext
 *
 * Description:
 *   Save the current thread context.  Full prototype is:
 *
 *   int  up_saveusercontext(uint32 *regs);
 *
 * Return:
 *   0: Normal return
 *   1: Context switch return
 *
 **************************************************************************/

	.text
	.thumb_func
	.globl		up_saveusercontext
	.type		up_saveusercontext, function
up_saveusercontext:

	/* Perform the System call with R0=0 and R1=regs */

	ldr	r2, nvic_intctrl	/* R2: Address NVIC INTCTRL registers */
	ldr	r3, [r2, #0]		/* R3: Content of NVIC INCTRL */
	orr	r3, r3, #NVIC_INTCTRL_PENDSVSET
	mov	r1, r0			/* R1: regs */
	mov	r0, #0			/* R0: 0 means save context (also return value) */
	str     r3, [r2, #0]		/* Force Pend SV */

	/* There are two return conditions.  On the first return, R0 (the
	 * return value will be zero.  On the second return we need to
	 * force R0 to be 1.
	 */

	add	r2, r1, #(4*REG_R0)
	mov	r3, #1
	str	r3, [r2, #0]
	bx	lr			/* "normal" return with r0=0 or
					 * context switch with r0=1 */
	.size		up_saveusercontext, .-up_saveusercontext


/**************************************************************************
 * Name: up_fullcontextrestore
 *
 * Description:
 *   Restore the current thread context.  Full prototype is:
 *
 *   void up_fullcontextrestore(uint32 *regs) __attribute__ ((noreturn));
 *
 * Return:
 *   None
 *
 **************************************************************************/

	.thumb_func
	.globl		up_fullcontextrestore
	.type		up_fullcontextrestore, function
up_fullcontextrestore:

	/* Perform the System call with R0=1 and R1=regs */

	ldr	r2, nvic_intctrl	/* R2: Address NVIC INTCTRL registers */
	ldr	r3, [r2, #0]		/* R3: Content of NVIC INCTRL */
	orr	r3, r3, #NVIC_INTCTRL_PENDSVSET
	mov	r1, r0			/* R1: regs */
	mov	r0, #1			/* R0: 1 means restore context */
	str     r3, [r2, #0]		/* Force Pend SV */

	/* This call should not return */

	bx	lr			/* Unnecessary ... will not return */
	.size		up_fullcontextrestore, .-up_fullcontextrestore

        .align  2
	.type		nvic_intctrl, object
nvic_intctrl:
        .word   NVIC_INTCTRL
	.size		nvic_intctrl, .-nvic_intctrl
        .end