1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
|
/*************************************************************************
* arch/z16/src/z16f/z16f_lowuart.asm
* Z16F UART management
*
* Copyright (C) 2008 Gregory Nutt. All rights reserved.
* Author: Gregory Nutt <spudmonkey@racsa.co.cr>
*
* Redistribution and use in source and binary forms, with or without
* modification, are permitted provided that the following conditions
* are met:
*
* 1. Redistributions of source code must retain the above copyright
* notice, this list of conditions and the following disclaimer.
* 2. Redistributions in binary form must reproduce the above copyright
* notice, this list of conditions and the following disclaimer in
* the documentation and/or other materials provided with the
* distribution.
* 3. Neither the name NuttX nor the names of its contributors may be
* used to endorse or promote products derived from this software
* without specific prior written permission.
*
* THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
* "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
* LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
* FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
* COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
* INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSeqUENTIAL DAMAGES (INCLUDING,
* BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS
* OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED
* AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
* LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
* ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
* POSSIBILITY OF SUCH DAMAGE.
*
*************************************************************************/
/*************************************************************************
* Included Files
*************************************************************************/
#include <nuttx/config.h>
#include <chip/chip.h>
#if defined(CONFIG_ARCH_LOWPUTC) || defined(CONFIG_ARCH_LOWGETC)
/*************************************************************************
* External References / External Definitions
*************************************************************************/
xdef z16f_lowuartinit
xref _SYS_CLK_FREQ:EROM
#ifdef CONFIG_ARCH_LOWPUTC
xdef _z16f_xmitc
xdef _up_lowputc
#endif
#ifdef CONFIG_ARCH_LOWGETC
xdef _up_lowgetc
#endif
/*************************************************************************
* Data Allocation
*************************************************************************/
/*************************************************************************
* Data Allocation
*************************************************************************/
define CODESEG, SPACE=EROM
segment CODESEG
/*************************************************************************
* Code
*************************************************************************/
/*************************************************************************
* Name: z16f_lowuartinit
*
* Description:
* Initialize UART0 or UART1
*
* Parameters:
* r1 = 0:UART0 1:UART1
* r2 = Frequency
* r3 = BAUD rate
*
*************************************************************************/
z16f_lowuartinit:
pushmlo <r0,R3> /* Save registers */
ld r3, #_SYS_CLK_FREQ
ld r0, R3
sll r0, #3
#ifdef CONFIG_UART0_SERIAL_CONSOLE
sll r0, #CONFIG_UART0_BAUD
#else
sll r0, #CONFIG_UART1_BAUD
#endif
sll R3, #4
udiv r0, R3 /* BRG = (freq + baud * 8)/(baud * 16) */
#ifdef CONFIG_UART0_SERIAL_CONSOLE
ld.w Z16F_UART0_BR, r0 /* Z16F_UART0_BR = BRG */
ld r0, #%30
or.b Z16F_GPIOA_AFL, r0 /* Z16F_GPIOA_AFL |= %30 */
clr.b Z16F_UART0_CTL1 /* Z16F_UART0_CTL1 = 0 */
ld 0, #%c0
ld.b Z16F_UART0_CTL0, r0 /* Z16F_UART0_CTL0 = %c0 */
#else
ld.w Z16F_UART1_BR, r0 /* Z16F_UART1_BR = BRG */
ld r0, #%30
or.b Z16F_GPIOD_AFL, r0 /* Z16F_GPIOD_AFL |= %30 */
clr.b Z16F_UART1_CTL1 /* Z16F_UART1_CTL1 = 0 */
ld r0, #%c0
ld.b Z16F_UART1_CTL0, r0 /* Z16F_UART1_CTL0 = %c0 */
#endif
popmlo <r0, R3> /* Restore registers */
ret /* Return */
/*************************************************************************
* Name: _z16f_xmitc
*
* Description:
* Send one character on the selected port
*
* Parmeters:
* r1 = character
*
*************************************************************************/
#ifdef CONFIG_ARCH_LOWPUTC
_z16f_xmitc:
pushmlo <r0> /* Save registers */
_z16f_xmitc1:
#ifdef CONFIG_UART0_SERIAL_CONSOLE
ld r0,#4
tm.b Z16F_UART0_STAT0,r0
jp eq, _z16f_xmitc1 /* While (!(Z16F_UART0_STAT0 & %4)) */
ld.b Z16F_UART0_TXD,r1 /* Z16F_UART0_TXD = r1 (character) */
#else
ld r0,#4
tm.b Z16F_UART1_STAT0,r0
jp eq, _z16f_xmitc1 /* While (!(Z16F_UART1_STAT0 & %4)) */
ld.b Z16F_UART1_TXD,r1 /* Z16F_UART1_TXD = r1 (character) */
#endif
popmlo <r0> /* Restore registers */
ret /* Return */
#endif
/*************************************************************************
* Name: _up_lowputc
*
* Description:
* Send one character to the selected serial console
*
* Parmeters:
* r1 = character
*
* Return
* R0 = 0
*
*************************************************************************/
#ifdef CONFIG_ARCH_LOWPUTC
_up_lowputc:
pushmlo <r1,r5> /* Save registers */
ld r0,r1
ext.ub r5,r0
cp r5,#10
jp ne, _up_lowputc1 /* If (character == \n) */
ld r1,#13
call _z16f_xmitc /* Call _z16f_xmitc with \r */
_up_lowputc1:
ld r1, r0
call _z16f_xmitc /* Xall _z16f_xmitc with character */
ld r0, #0 /* return r0 = 0 */
popmlo <r1,r5> /* Restore registers */
ret /* Return */
#endif
/*************************************************************************
* Name: _up_lowgetc
*
* Description:
* Get a character from the serial port
*
* Parmeters:
* None
*
* Return
* R0 = Character read
*
*************************************************************************/
#ifdef CONFIG_ARCH_LOWGETC
_up_lowgetc:
up_lowgetc1:
ld r0, #%80
#ifdef CONFIG_UART0_SERIAL_CONSOLE
tm.b Z16F_UART0_STAT0,r0
jp eq, _up_lowgetc1 /* While (!Z16F_UART0_STAT0 & %80)) */
ld.ub r0, Z16F_UART0_RXD /* r0 = Z16F_UART0_RXD */
#else
tm.b Z16F_UART1_STAT0,r0 /* While (!Z16F_UART1_STAT0 & %80) */
jp eq, _up_lowgetc1
ld.ub r0, Z16F_UART1_RXD /* r0 = Z16F_UART1_RXD */
#endif
cp r0, #%0d /* Test for '\r' */
jp eq, _up_lowgetc2
cp r0, #%0d /* Test \r + high bit */
jp ne, _up_lowgetc3
_up_lowgetc2:
ld r0, #%0a /* Convert '\r' to '\n' */
_up_lowgetc3: /* Return value in r0 */
ret /* Return */
#endif
#endif /* CONFIG_ARCH_LOWPUTC || CONFIG_ARCH_LOWGETC */
end
|
